Phần mềm In file từ thiết bị di động trên máy tính thông qua Dropbox

Thảo luận trong 'Windows' bắt đầu bởi VanHelsing, 12 Tháng mười một 2013.

  1. Có nhiều cách để in file từ thiết bị di động trên máy tính để bàn nhưng hầu hết đều khá phức tạp. Hôm nay Congnghe.5giay sẽ giới thiệu cho các bạn cách thức rất đơn giản dựa trên công cụ phổ biến hiện nay là Dropbox .

    In file từ thiết bị di động trên máy tính thông qua Dropbox - 4206

    Bước 1: Cài Dropbox trên PC và các thiết bị di động của bạn.
    Phiên bản cho Windows: https://www.dropbox.com/downloading?os=win
    Mac OS: https://www.dropbox.com/downloading?os=mac
    Linux: https://www.dropbox.com/downloading?os=lnx
    Các hệ điều hành mobile: iOS, Android, BlackBerry

    Bước 2: Tải về file script sau đây và sử dụng trên máy cài Windows và có máy in. http://img.labnol.org/files/17827/eprint.zip

    In file từ thiết bị di động trên máy tính thông qua Dropbox - 4207

    Bước 3: Mở file eprint.vbs và nhấp đôi để cài vào máy. Sau khi hoàn tấtbaạn sẽ có được 1 folder "PrintQueue" trong folder Dropbox của bạn.

    In file từ thiết bị di động trên máy tính thông qua Dropbox - 4208

    Bước 4: Upload file cần in vào folder PrintQueue, máy in của bạn sẽ tự động in ra file đó.

    Và đừng quên bật sẵn máy in nhé ^^
    Chủ đề tương tự
    Last edited by a moderator: 14 Tháng mười một 2013
    chuaxam thích bài này.
  2. cpc

    cpc Rất To Group!

    click vào link nhưng ko tải được cái script này, giờ sao nhỉ :confused:
  3. VanHelsing

    VanHelsing Guest

  4. VanHelsing

    VanHelsing Guest

    Ai không tải đc thì có thể copy đoạn sau vào notepad và save lại thành file vbs
    Mã:
    'Remote Printing through Dropbox
    'Written by Amit Agarwal http://www.labnol.org/
    Option Explicit
    On Error Resume Next
    Const WAIT_TIME  = 5000 '5 seconds
    Const PRINT_TIME = 5000 '5 seconds
    Dim WshShell, fso, configFile, objReadFile, str64, strPath, ApplicationData
    Dim dbWatchDir, attFolder, objShell, objFolder, colItems, objItem, dbLogDir, logFolder, doneFolder
    Set WshShell = CreateObject("Wscript.Shell")
    Set fso = CreateObject("Scripting.FileSystemObject")
    ApplicationData = WshShell.ExpandEnvironmentStrings("%APPDATA%")
    'Find the Dropbox Folder Location
    configFile = ApplicationData & "\Dropbox\host.db"
    If fso.FileExists( configFile ) Then
    Set objReadFile = fso.OpenTextFile( configFile, 1)
    Do Until objReadFile.AtEndOfStream
      str64 = objReadFile.ReadLine
    Loop
    strPath = Base64Decode(str64)
    'WScript.Echo "Your Dropbox folder is located at " & strPath
    Else
    WScript.Echo "Looks like Dropbox is not installed on this computer." &  VbCrLf & "Please install Dropbox and run this script again."
    WScript.Quit()
    End If
    dbWatchDir = strPath & "\Attachments"
    If Not fso.FolderExists (dbWatchDir) Then
    Set attFolder = fso.CreateFolder (dbWatchDir)
    WScript.Echo "Created a folder to hold your new print jobs - " & dbWatchDir
    End If
    dbLogDir = dbWatchDir & "\Print_Log"
    If Not fso.FolderExists (dbLogDir) Then
    Set logFolder = fso.CreateFolder (dbLogDir)
    WScript.Echo "Created a folder to hold processed jobs - " & dbLogDir
    End If
    Do While True
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.Namespace(dbWatchDir)
    Set colItems = objFolder.Items
    doneFolder = dbLogDir & "\" & DateDiff("s", "1/1/2010", Now)
    For Each objItem in colItems
    If Not objItem.IsFolder Then 
      If Not fso.FolderExists (doneFolder) Then
      Set logFolder = fso.CreateFolder (doneFolder)
      WScript.Echo "Created a folder to save processed jobs - " & doneFolder
      End If
      objItem.InvokeVerbEx("Print")
      WScript.Echo "Now printing: " & objItem.Name 
      WScript.Sleep(PRINT_TIME)
      fso.MoveFile dbWatchDir & "\" & objItem.Name & "*", doneFolder
    end if
    Next
    WScript.Sleep(WAIT_TIME)
    Set objShell = nothing
    Set objFolder = nothing
    Set colItems = nothing
    Loop
    ' Decodes a base-64 encoded string (BSTR type).
    ' 1999 - 2004 Antonin Foller, http://www.motobit.com
    Function Base64Decode(ByVal base64String)
      Const Base64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
      Dim dataLength, sOut, groupBegin
      base64String = Replace(base64String, vbCrLf, "")
      base64String = Replace(base64String, vbTab, "")
      base64String = Replace(base64String, " ", "")
      dataLength = Len(base64String)
      If dataLength Mod 4 <> 0 Then
        Err.Raise 1, "Base64Decode", "Bad Base64 string."
        Exit Function
      End If
      For groupBegin = 1 To dataLength Step 4
        Dim numDataBytes, CharCounter, thisChar, thisData, nGroup, pOut
        numDataBytes = 3
        nGroup = 0
        For CharCounter = 0 To 3
          thisChar = Mid(base64String, groupBegin + CharCounter, 1)
          If thisChar = "=" Then
            numDataBytes = numDataBytes - 1
            thisData = 0
          Else
            thisData = InStr(1, Base64, thisChar, vbBinaryCompare) - 1
          End If
          If thisData = -1 Then
            Err.Raise 2, "Base64Decode", "Bad character In Base64 string."
            Exit Function
          End If
          nGroup = 64 * nGroup + thisData
        Next
     
        nGroup = Hex(nGroup)
        nGroup = String(6 - Len(nGroup), "0") & nGroup
     
        pOut = Chr(CByte("&H" & Mid(nGroup, 1, 2))) + _
          Chr(CByte("&H" & Mid(nGroup, 3, 2))) + _
          Chr(CByte("&H" & Mid(nGroup, 5, 2)))
     
        sOut = sOut & Left(pOut, numDataBytes)
      Next
      Base64Decode = sOut
    End Function
  5. cpc

    cpc Rất To Group!

Chia sẻ trang này